12-26-96.html

Maple V 的基本繪圖指令

plot, draw及 animate

清華大學

全任重

開場白

數學是由許多複雜的關係所構成的。解決數學問題

的要領在於能否順利的由某些關係轉移到其他的關

係。人們透過邏輯、分析、運算、比擬、圖形、轉

換、推廣等各種方式來瞭解數學﹐其目的是使得處

於複雜的關係之間能夠通行無阻的活動。電腦軟體

裏的符號運算功能提供代數運算的能力﹐使得人們

依據非傳統的步驟來理解數學。Maple V 提供了一

個簡易操作而具有強大計算功能的代數運算環境。

要如何應用這套軟體來瞭解數學卻是一件不能由使

用手冊交代清楚之事。考慮以下這個問題:

問題:

求函數

的導函數。

計算:

> diff(abs(abs(x-1)+abs(x+1)-2)-(abs(x-1)+abs(x+1)),x);

> simplify(%);

不同的效果

這是不經思考的代數運算的處理。然而﹐如果當初所挑選的

不是代數運算而是繪圖指令﹐效果卻大不相同。

> plot(abs(abs(x-1)+abs(x+1)-2)-(abs(x-1)+abs(x+1)),x=-3..3);

[Maple Plot]

所以:

看起來原本給定的只不過是個常數函數而已!還有必

要依賴電腦來求其導函數嗎﹖這個例子說明:

電腦的使用策略之重要性不亞於使用方法之重要性。

除了代數運算以外﹐Maple V 的繪圖功能可以

增強我們對於數學的瞭解。

呈現數學概念的基本指令---plot, draw及 animate

plot

形如y=f(x)的函數圖形

例: 函數y=sin(x),-6<=x<=6的圖形

> plot(sin(x),x=-6..6);

[Maple Plot]

極坐標函數圖形

例: 函數r=sin(6x),0<=x<=6的圖形

> plot([sin(6*x),x,x=0..2*Pi],coords=polar);

[Maple Plot]

參數曲線圖

例: 函數x=sin(9t),y=cos(10t),0<t<10的圖形

> plot([sin(9*t), cos(10*t), t=0..10]);

[Maple Plot]

plot3d

形如 z=f(x,y) 的函數圖形

�: 函數z=x^2+y^2,-1<x<1,-1,<y<1的圖形

> plot3d(x^2+y^2,x=-1..1,y=-1..1);

[Maple Plot]

圓柱坐標函數圖形

�:�: 函數 r=θ, 0<θ<8π,-1<z<1的圖形

> plot3d(theta,theta=0..8*Pi,z=-1..1, coords=cylindrical, style=patch);

[Maple Plot]

球坐標函數圖形

例: 函數ρ=θ, 0<θ<3π, 0<φ<π的圖形

> plot3d(theta,theta=0..3*Pi,phi=0..Pi, coords=spherical);

[Maple Plot]

一般參數曲面圖

> c1:= [cos(x)-2*cos(0.4*y),sin(x)-2*sin(0.4*y),y]:

> c2:= [cos(x)+2*cos(0.4*y),sin(x)+2*sin(0.4*y),y]:

> c3:= [cos(x)+2*sin(0.4*y),sin(x)-2*cos(0.4*y),y]:

> c4:= [cos(x)-2*sin(0.4*y),sin(x)+2*cos(0.4*y),y]:

> plot3d({c1,c2,c3,c4},x=0..2*Pi,y=0..10,grid=[25,15],style=patch,color=sin(x));

[Maple Plot]

平面幾何之draw

Maple V提供不少平面幾何之作圖程序。使用這些程序之前必須下指令

> with(geometry);

以下是平面幾何之作圖的一些實例

三角形及其外接圓

> triangle(T,[point(A2,0,0),point(A1,2,4),point(A3,7,0)]):

circumcircle(C,T,'centername'=OO):

draw({C,T});

[Maple Plot]

中線定理

> median(A1M1,A1,T,M1):

median(A2M2,A2,T,M2):

median(A3M3,A3,T,M3):

draw({T,A1M1,A2M2,A3M3});

[Maple Plot]

Appolonius作圖問題

求作同時與給出的三個圓相切的八個圓。

> circle(c1, (x+3)^2 + y^2 = 4, [x,y]):
circle(c2,[point(O1,6,0),3],[x,y]):
circle(c3, x^2 + (y-7)^2 = 1, [x,y]):
App := Appolonius(c1, c2, c3):

> draw([c1(color=plum),c2(color=plum),c3(color=plum),op(App)],
scaling=constrained,printtext=false,axes=none,filled=true,
color=yellow,style=line,title=`Appolonius Circles`);

[Maple Plot]

Gergonne點

> triangle(T, [point(A,0,0), point(B,2,1), point(C,1,3)]):

GergonnePoint(G, T);

incircle(c,T):
segment(sg1,A,projection(H,center(c),line(tmp,[B,C]))):
segment(sg2,B,projection(E,center(c),line(tmp,[C,A]))):

segment(sg3,C,projection(F,center(c),line(tmp,[A,B]))):

### WARNING: the definition of the type `symbol` has changed'; see help page for details
draw({sg1,sg2,sg3,c(color=green,style=POINT),G(symbol=DIAMOND),T(color=red)}, color=blue,printtext=true);